Add RevBank::Accounts::delete

lib/RevBank/Accounts.pm

@@ -80,6 +80,25 @@ sub create($account) {
     return $account;
 }
 
+sub delete($account) {
+    die "No such account" if RevBank::Accounts::is_special $account;
+
+    my $user_found = 0;
+    rewrite $filename, sub($line) {
+        my @a = split " ", $line;
+        if (lc $a[0] ne lc $account) {
+            return $line;
+        }
+        if ($a[1] != 0) {
+            die "Account $account still has balance";
+        }
+        $user_found = 1;
+        return "";
+    };
+
+    die "No such account" if not $user_found;
+}
+
 sub update($account, $delta, $transaction_id) {
     $account = assert_account($account);
 

lib/RevBank/Accounts.pod

@@ -126,6 +126,12 @@ Creates an account with that name and a balance of zero. The name must not alrea
 
 After updating the file, calls the C<account_created> hook with the account name.
 
+=head3 delete($name)
+
+Deletes an account.
+
+Special accounts may not be deleted via this method. The account must have a balance of 0.00.
+
 =head3 update($name, $delta, $transaction_id)
 
 Given the relative change (C<$delta>), updates the user balance for an account.

plugins/deluser

@@ -0,0 +1,51 @@
+#!perl
+
+use List::Util qw(any);
+
+HELP1 "deluser <name>" => "Delete an account";
+
+our $contra = "+donations";
+
+sub command :Tab(deluser) ($self, $cart, $command, @) {
+    $command eq 'deluser' or return NEXT;
+
+    return "Name of the account to be deleted", \&confirm_delete;
+}
+
+sub confirm_delete($self, $cart, $name, @) {
+    my $amount = RevBank::Accounts::balance($name);
+
+    return ABORT, "No such account."
+        if (not defined $amount);
+
+    return ABORT, "Can not delete an account with a negative balance."
+        if ($amount < 0);
+
+    $self->{name} = $name;
+
+    print "This will delete account $name and donate the remaining $amount.\n";
+
+    return "Are you sure? Type DONATE_AND_DELETE to proceed", \&delete_account;
+}
+
+sub delete_account($self, $cart, $confirmation, @) {
+    return REJECT, "Type DONATE_AND_DELETE to proceed"
+        if ($confirmation ne "DONATE_AND_DELETE");
+
+    my $amount = RevBank::Accounts::balance($self->{name});
+
+    RevBank::FileIO::with_lock {
+        if ($amount > 0) {
+            my $contra_account = RevBank::Accounts::assert_account($contra);
+            my $transaction_id = "";
+            RevBank::Accounts::update($self->{name}, -$amount, $transaction_id);
+            RevBank::Accounts::update($contra_account, $amount, $transaction_id);
+        }
+
+        RevBank::Accounts::delete($self->{name});
+    };
+
+    print "Account $self->{name} deleted.";
+
+    return ACCEPT;
+}