refactor(default-flatpaks): version 2 (nushell)

modules/default-flatpaks/v2/default-flatpaks.sh

@@ -0,0 +1,83 @@
+#!/usr/bin/env nu
+
+const flathubURL = "https://dl.flathub.org/repo/flathub.flatpakrepo"
+
+const defaultConfiguration = {
+    notify: true
+    scope: user
+    repo: {
+        url: $flathubURL
+        name: "flathub"
+        title: "Flathub"
+    }
+    install: []
+}
+
+const usrSharePath = "/usr/share/bluebuild/default-flatpaks"
+const configPath = $"($usrSharePath)/configuration.yaml"
+
+def main [configStr: string] {
+    let config = $configStr | from yaml
+
+    let configurations = $config.configurations | each {|configuration|
+        mut merged = $defaultConfiguration | merge $configuration
+        $merged.repo = $defaultConfiguration.repo | merge $merged.repo # make sure all repo properties exist
+
+        print $"Validating configuration of (ansi default_italic)($merged.install | length)(ansi reset) Flatpaks from (ansi default_italic)($merged.repo.title)(ansi reset)"
+
+        if (not ($merged.scope == "system" or $merged.scope == "user")) {
+            print $"(ansi red_bold)Scope must be either(ansi reset) (ansi blue_italic)system(ansi reset) (ansi red_bold)or(ansi reset) (ansi blue_italic)user(ansi reset)"
+            print $"(ansi blue)Your input:(ansi reset) ($merged.scope)"
+            exit 1
+        }
+        if (not ($merged.notify == true or $merged.notify == false)) {
+            print $"(ansi red_bold)Notify must be either(ansi reset) (ansi blue_italic)true(ansi reset) (ansi red_bold)or(ansi reset) (ansi blue_italic)false(ansi reset)"
+            print $"(ansi blue)Your input:(ansi reset) ($merged.notify)"
+            exit 1
+        }
+        if ($merged.repo.url == $flathubURL) {
+            checkFlathub $merged.install
+        }
+
+        print $"Validation successful!"
+
+        $merged
+    }
+
+
+    if (not ($configPath | path exists)) {
+        mkdir ($configPath | path dirname)
+        '[]'| save $configPath
+    }
+
+    open $configPath
+        | append $configurations
+        | to yaml | save -f $configPath
+
+    print $"(ansi green_bold)Successfully generated following configurations:(ansi reset)"
+    print ($configurations | to yaml)
+
+    print "Setting up Flatpak setup services..."
+
+    cp -r ($"($env.MODULE_DIRECTORY)/default-flatpaks/post-boot/*" | into glob) $usrSharePath
+
+    cp $"($usrSharePath)/system-flatpak-setup.service" /usr/lib/systemd/system/system-flatpak-setup.service
+    cp $"($usrSharePath)/user-flatpak-setup.service" /usr/lib/systemd/user/user-flatpak-setup.service
+    systemctl enable --force system-flatpak-setup.service
+    systemctl enable --force --global user-flatpak-setup.service
+
+    chmod +x $"($usrSharePath)/system-flatpak-setup"
+    chmod +x $"($usrSharePath)/user-flatpak-setup"
+}
+
+def checkFlathub [packages: list<string>] {
+    print "Checking if configured packages exist on Flathub..."
+    $packages | each { |package| 
+        try {
+            let _ = http get $"https://flathub.org/apps/($package)"
+        } catch {
+            print $"(ansi red_bold)Package(ansi reset) (ansi default_italic)($package)(ansi reset) (ansi red_bold)does not exist on Flathub, which is the specified repository for it to be installed from.(ansi reset)"
+            exit 1
+        }
+    }
+}

modules/default-flatpaks/v2/post-boot/system-flatpak-setup

@@ -0,0 +1,41 @@
+#!/usr/bin/env nu
+
+const usrSharePath = "/usr/share/bluebuild/default-flatpaks"
+const configPath = $"($usrSharePath)/configuration.yaml"
+
+def main [] {
+    let configFile = open $configPath
+
+    if (flatpak remotes | str contains fedora) {
+        /usr/bin/gnome-software --quit
+        /usr/lib/fedora-third-party/fedora-third-party-opt-out
+        /usr/bin/fedora-third-party disable
+
+        flatpak remote-delete --system fedora --force
+        flatpak remote-delete --system fedora-testing --force
+
+        # TODO remove Fedora Flatpaks
+    }
+
+    $configFile.configurations | where scope == system | each { |config|
+        flatpak remote-add --system --if-not-exists $config.repo.name $config.repo.url --title $config.repo.title
+
+        if ($config.notify) {
+            # TODO implement notification sending
+            # (notify-send 
+            #     --app-name "Automatic Flatpak Installation Service"
+            #     $"Starting automated installation of ($config.install | length) Flatpak\(s) from ($config.repo.title)..."
+            # )
+        }
+
+        flatpak install --system $config.repo.name ...$config.install
+
+        if ($config.notify) {
+            # (notify-send 
+            #     --app-name "Automatic Flatpak Installation Service"
+            #     $"Finished automated installation of ($config.install | length) Flatpak\(s) from ($config.repo.title)!"
+            #     ($config.install | str join ', ')
+            # )
+        }
+    }
+}

modules/default-flatpaks/v2/post-boot/system-flatpak-setup.service

@@ -0,0 +1,14 @@
+[Unit]
+Description=Manage system flatpaks
+Wants=network-online.target
+After=network-online.target
+
+[Service]
+Type=oneshot
+ExecStart=/usr/share/bluebuild/default-flatpaks/system-flatpak-setup
+Restart=on-failure
+RestartSec=30
+StartLimitInterval=0
+
+[Install]
+WantedBy=multi-user.target

modules/default-flatpaks/v2/post-boot/user-flatpak-setup

@@ -0,0 +1,34 @@
+#!/usr/bin/env nu
+
+const usrSharePath = "/usr/share/bluebuild/default-flatpaks"
+const configPath = $"($usrSharePath)/configuration.yaml"
+
+def main [] {
+    let configFile = open $configPath
+
+    if (flatpak remotes | str contains fedora) {
+        flatpak remote-delete --user fedora --force
+        flatpak remote-delete --user fedora-testing --force
+    }
+
+    $configFile.configurations | where scope == user | each { |config|
+        flatpak remote-add --user --if-not-exists $config.repo.name $config.repo.url --title $config.repo.title
+
+        if ($config.notify) {
+            (notify-send 
+                --app-name "Automatic Flatpak Installation Service"
+                $"Starting automated installation of ($config.install | length) Flatpak\(s) from ($config.repo.title)..."
+            )
+        }
+
+        flatpak install --user $config.repo.name ...$config.install
+
+        if ($config.notify) {
+            (notify-send 
+                --app-name "Automatic Flatpak Installation Service"
+                $"Finished automated installation of ($config.install | length) Flatpak\(s) from ($config.repo.title)!"
+                ($config.install | str join ', ')
+            )
+        }
+    }
+}

modules/default-flatpaks/v2/post-boot/user-flatpak-setup.service

@@ -0,0 +1,14 @@
+[Unit]
+Description=Configure Flatpaks for current user
+Wants=network-online.target
+After=system-flatpak-setup.service
+
+[Service]
+Type=simple
+ExecStart=/usr/share/bluebuild/default-flatpaks/user-flatpak-setup
+Restart=on-failure
+RestartSec=30
+StartLimitInterval=0
+
+[Install]
+WantedBy=default.target