build.gradle

plugins {
    alias(libs.plugins.axionRelease)
    id 'java'
}

group 'org.rundeck.plugins'

ext.rundeckPluginVersion = '1.2'
ext.publishName = "Git Plugin ${project.version}"
ext.githubSlug = 'rundeck-plugins/git-plugin'
ext.pluginClassNames='com.rundeck.plugin.GitResourceModelFactory,com.rundeck.plugin.GitCloneWorkflowStep,com.rundeck.plugin.GitPushWorkflowStep,com.rundeck.plugin.GitCommitWorkflowStep,com.rundeck.plugin.GitAddWorkflowStep'
ext.pluginName = 'Git Plugin'
ext.pluginDescription = 'This is a git plugin (based on Jgit) which contain a Resource model and worflow steps'
ext.developers = [
        [id: 'ltamaster', name: 'Luis Toledo', email: 'luis@variacode.com']
]


java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    withJavadocJar()
    withSourcesJar()
}

scmVersion {
    ignoreUncommittedChanges = false
    tag {
        prefix = ''           // NO "v" prefix - see PLUGIN_TAGGING_ARCHITECTURE.md
        versionSeparator = ''
    }
    versionCreator 'simple'  // Use simple version creator (just tag name)
}
project.version = scmVersion.version

apply plugin: 'groovy'
apply plugin: 'java'

repositories {
    mavenCentral()
    maven {
        name = 'Central Portal Snapshots'
        url = 'https://central.sonatype.com/repository/maven-snapshots/'
        content {
            includeGroup('org.rundeck')
        }
    }
}

configurations {
    pluginLibs

    implementation {
        extendsFrom pluginLibs
    }
}


dependencies {
    // Use catalog aliases for dependencies
    implementation(libs.groovyAll)
    compileOnly(libs.rundeckCore)
    testImplementation(libs.rundeckCore)
    implementation(libs.slf4jApi)
    
    // Add secure commons-lang3 to provide alternative to vulnerable commons-lang 2.6
    implementation(libs.commonsLang3)

    pluginLibs(libs.jgit) {
        exclude module: 'slf4j-api'
        exclude module: 'commons-logging'
    }

    pluginLibs(libs.jgitSshApache) {
        exclude module: 'slf4j-api'
    }

    testImplementation libs.bundles.testLibs
}

configurations.all {
    resolutionStrategy {
        // Force secure versions for non-breaking dependency overrides
        force "com.squareup.okhttp3:okhttp:${libs.versions.okhttp3.get()}"
        force "com.squareup.okio:okio:${libs.versions.okio.get()}"
        
        // Replace vulnerable commons-lang with secure commons-lang3
        dependencySubstitution {
            substitute module('commons-lang:commons-lang') using module("org.apache.commons:commons-lang3:${libs.versions.commonsLang3.get()}")
        }
        
    }
}


task copyToLib(type: Copy) {
    into "$buildDir/output/lib"
    from configurations.pluginLibs
}

jar {
    from "$buildDir/output"
    manifest {
        def libList = configurations.pluginLibs.collect{'lib/' + it.name}.join(' ')
        attributes 'Rundeck-Plugin-Name' : pluginName
        attributes 'Rundeck-Plugin-Description' : pluginDescription
        attributes 'Rundeck-Plugin-Rundeck-Compatibility-Version': '2.11.4+'
        attributes 'Rundeck-Plugin-Tags': 'java,workflow steps,resource model'
        attributes 'Rundeck-Plugin-License': 'Apache 2.0'
        attributes 'Rundeck-Plugin-Source-Link': 'https://github.com/rundeck-plugins/git-plugin'
        attributes 'Rundeck-Plugin-Target-Host-Compatibility': 'all'
        attributes 'Rundeck-Plugin-Author': 'Rundeck, Inc.'
        attributes 'Rundeck-Plugin-Classnames': pluginClassNames
        attributes 'Rundeck-Plugin-File-Version': project.version
        attributes 'Rundeck-Plugin-Version': rundeckPluginVersion
        attributes 'Rundeck-Plugin-Archive': 'true'
        attributes 'Rundeck-Plugin-Libs': "${libList}"
    }
    dependsOn(copyToLib)
}

test {
    useJUnitPlatform()
    // Java 17 requires these for cglib/Spock mocking
    jvmArgs '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
            '--add-opens', 'java.base/java.util=ALL-UNNAMED'
}

apply from: "${rootDir}/gradle/publishing.gradle"

def pkgcldRepoUrl = (System.getenv("PKGCLD_REPO_URL") ?: "https://packagecloud.io/pagerduty/rundeck-plugins/maven2").trim()

publishing {
    repositories {
        maven {
            name = "PackageCloud"
            url = uri(pkgcldRepoUrl)
            authentication {
                header(HttpHeaderAuthentication)
            }
            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "Bearer " + (System.getenv("PKGCLD_WRITE_TOKEN") ?: project.findProperty("pkgcldWriteToken"))
            }
        }
    }
}