MultiCompartmentModel/KCC2_SA.mod at master · annikc/MultiCompartmentModel · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
:------------------------------------------------------------------------------
TITLE Model of KCC2 transport
:------------------------------------------------------------------------------

COMMENT
-----------------------------------------------------------------------------
  This file models the KCC2 channel mechanism as a distributed process to
  extrude intracellular chloride to baseline levels and increase chloride
  concentration in the presence of chloride currents.

  A tonic GABA component is included to maintain chloride levels and is
  equal but opposite to the initial extrusion rate of chloride ions.

  The internal chloride ion concentration should be explicitly set in hoc
  after inserting KCC2 but before running using
  "cli0_KCC2 = x"
  else the default of 5 mM is used.

  With special thanks to Blake Richards and lab

  Authors: Christopher Brian Currin, Joseph Valentino Raimondo

  References:
  -
-----------------------------------------------------------------------------
ENDCOMMENT

NEURON {
  SUFFIX KCC2_Transport : KCC2_SA
  USEION cl READ icl, ecl, clo WRITE cli VALENCE -1
  USEION k READ ki, ko VALENCE 1
  USEION mkcc2 READ mkcc2i VALENCE 1
  RANGE axD, gtonic, itonic
  RANGE R_T, r_T
  RANGE D, v_T, V_T, transport
  RANGE efflux, Pa
  GLOBAL celsius
}

UNITS {
    (mV) = (millivolt)
    (um) = (micron)
  (mA) = (milliamp)
  (M)  = (1/liter)
  (mM) = (milliM)
  (J)  = (joule)
  (S)  = (siemens)
  F    = (faraday) (coulombs)
  R    = (k-mole) (joule/degC)
  PI   = (pi) (1)
}

PARAMETER {
  Pa     = 1.9297e-5   (mA/mM2/cm2)
  axD    = 1    (um2/ms) < 0, 1e9 > : axial chloride diffusion constant
  gtonic = 2.12e-6     (S/cm2)  : tonic conductance
}

ASSIGNED {
  v         (mV)     : membrane voltage
  diam      (um)     : compartment diameter
  L         (um)     : compartment length
  icl       (mA/cm2) : chloride current
  ik        (mA/cm2) : potassium current
  itonic    (mA/cm2) : tonic GABA current
  clo       (mM)     : external chloride concentration
  ko        (mM)     : external potassium concentration
  ecl       (mV)     : chloride reversal potential
  celsius   (degC)   : temperature
  mkcc2i    (mM)     : concentration of membrane-bound KCC2
  D         ()     : KCC2 driving force direction
  v_T       (mM/s)   : rate of ion transport by KCC2
}

STATE {
  cli (mM) : internal chloride concentration
  ki  (mM) : internal potassium concentration
}

INITIAL {
  itonic    = 0
  D         = 0
  v_T       = 0
}

BREAKPOINT {
  SOLVE state METHOD sparse
}

KINETIC state {
  tonicgaba(v,ecl)
  transport_mm(cli, clo, ki, ko, mkcc2i)

  COMPARTMENT                PI*diam*diam/4 { cli }
  LONGITUDINAL_DIFFUSION axD*PI*diam*diam/4 { cli }

  : synaptic chloride current - KCC2 efflux + tonic GABA current
  ~ cli << ((1e4)*icl*diam*PI/F - (1e4)*v_T*PI*diam/F + (1e4)*itonic*diam*PI/F)
}

PROCEDURE tonicgaba(Vm (mV), Em (mV)) {
  itonic = gtonic * (Vm - Em)
}

PROCEDURE transport_mm(Clint (mM), Clout (mM), Kint (mM), Kout (mM), Mkcc2int (mM)) {
  v_T = Pa*(Kint*Clint-Kout*Clout)*(Mkcc2int)
}