build.gradle.kts

import gg.meza.stonecraft.mod

plugins {
    id("gg.meza.stonecraft")
}

val minecraft = stonecutter.current.version
val unobfuscated = stonecutter.eval(minecraft, ">=26.1")

repositories {
    mavenCentral()
    maven("https://maven.creeperhost.net/") { name = "CreeperHost" }
    maven("https://api.modrinth.com/maven") {
        name = "Modrinth"
        content { includeGroup("maven.modrinth") }
    }
    maven("https://cursemaven.com") {
        name = "CurseMaven"
        content { includeGroup("curse.maven") }
    }
    maven("https://maven.shedaniel.me/") { name = "Shedaniel" }
    maven("https://maven.terraformersmc.com/releases/") { name = "TerraformersMC" }
    maven("https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1") { name = "DevAuth" }
}

// Refined Storage 1.x is only on Modrinth's maven; 2.x and later publish a jar per loader to CreeperHost
val refinedStorage = when {
    mod.hasProp("rs_modrinth_id") -> "maven.modrinth:refined-storage:${mod.prop("rs_modrinth_id")}"
    else -> "com.refinedmods.refinedstorage:refinedstorage-${mod.loader}:${mod.prop("rs_version")}"
}

dependencies {
    val compile = if (unobfuscated) "compileOnly" else "modCompileOnly"
    val runtime = if (unobfuscated) "localRuntime" else "modLocalRuntime"

    add(compile, refinedStorage)
    add(runtime, refinedStorage)

    // Reborn Storage's Advanced Wireless Transmitter takes the cards too. Compile only, as it's optional
    if (mod.hasProp("rebornstorage_file")) {
        add(compile, "curse.maven:rebornstorage-256662:${mod.prop("rebornstorage_file")}")
    }

    if (mod.isFabric) {
        // Cloth Config backs the config on Fabric; ModMenu is optional and only adds the in-game config button
        add(if (unobfuscated) "api" else "modApi", "me.shedaniel.cloth:cloth-config-fabric:${mod.prop("cloth_config_version")}") {
            exclude(group = "net.fabricmc.fabric-api")
        }
        add(compile, "com.terraformersmc:modmenu:${mod.prop("modmenu_version")}")
        add(runtime, "com.terraformersmc:modmenu:${mod.prop("modmenu_version")}")
        // Refined Storage jar-in-jars Team Reborn Energy, but dev runs don't pick the nested copy up
        add(runtime, "teamreborn:energy:${mod.prop("tr_energy_version")}")
    }

    // Lets runClient sign in with a real Microsoft account. Dev runtime only, so it isn't in the built jar
    add(runtime, "me.djtheredstoner:DevAuth-${if (mod.isForge) "forge-latest" else mod.loader}:${property("devauth_version")}")
}

stonecutter {
    // Refined Storage 2 (1.21+) is a rewrite with a different API to Refined Storage 1
    constants.put("rs2", stonecutter.eval(minecraft, ">=1.21"))

    // Minecraft renamed ResourceLocation to Identifier in 1.21.11
    replacements.string(stonecutter.current.parsed < "1.21.11") {
        replace("Identifier", "ResourceLocation")
    }
}

// Fabric has no datagen here, so it reuses the NeoForge recipes and models for the same Minecraft version
if (mod.isFabric) {
    sourceSets.main {
        // From 1.21.4 the generated files land in a client/ folder
        val client = if (stonecutter.eval(minecraft, ">=1.21.4")) "/client" else ""
        resources.srcDir(rootProject.file("versions/$minecraft-neoforge/src/main/generated$client"))
    }
}

// Forge 1.20.1 treats every classpath folder as its own mod and crashes on the bare generated folder Stonecraft adds,
// so fold the generated files into the normal resources instead
if (mod.isForge) {
    val generated = file("src/main/generated")
    sourceSets.main {
        resources.srcDir(generated)
    }
    afterEvaluate {
        tasks.withType<JavaExec>().configureEach {
            classpath = classpath.filter { it != generated }
        }
    }
}

// Forge 1.15.2 and 1.16.5 run on Java 8, but Stonecraft compiles everything from 1.20.5 down with Java 17
if (stonecutter.eval(minecraft, "<1.17")) {
    tasks.withType<JavaCompile>().configureEach {
        options.release.set(8)
    }
}

// The game test framework arrived in 1.17, so there's nothing for chiseledGameTest to run before that. Forge's older
// userdev has no game test run either, and Loom fails on a run without a main class even when it's skipped
if (stonecutter.eval(minecraft, "<1.17")) {
    loom.runs.named("gameTestServer") {
        mainClass.set("none")
    }
    gradle.projectsEvaluated {
        tasks.named("runGameTestServer") {
            enabled = false
        }
    }
}

// Forge 1.15.2 itself only starts on Java 8, as it needs the Nashorn engine that later Java versions removed
if (stonecutter.eval(minecraft, "<1.16")) {
    tasks.withType<JavaExec>().configureEach {
        javaLauncher.set(javaToolchains.launcherFor { languageVersion.set(JavaLanguageVersion.of(8)) })
    }
}

// DevAuth supplies the real account name, and Minecraft refuses a second --username from Stonecraft's defaults
afterEvaluate {
    loom.runs.named("client") {
        programArguments.set(programArguments.get().filterNot { it.startsWith("--username") })
    }
}

tasks.named<Jar>("jar") {
    // Datagen bookkeeping stays in git but not in the jar
    exclude(".cache/**")
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

loom {
    runs.named("client") {
        jvmArguments.add("-Ddevauth.enabled=true")
    }
    // Forge 1.15's early loading window needs LWJGL natives that don't exist for Apple Silicon, and datagen has no use for it
    if (stonecutter.eval(minecraft, "<1.16")) {
        runs.configureEach {
            jvmArguments.add("-Dfml.earlyprogresswindow=false")
        }
    }
    if (mod.isForge) {
        forge {
            mixinConfig("${mod.id}.mixins.json")
        }
        // Without this Forge loads the classes and resources folders as two separate mods
        mods {
            register(mod.id) {
                sourceSet(sourceSets.main.get())
            }
        }
    }
}

modSettings {
    runDirectory = rootProject.layout.projectDirectory.dir("run/${project.name}")
    variableReplacements = mapOf(
        "authors" to project.property("mod.authors").toString(),
        "license" to project.property("mod.license").toString(),
        "rsVersionRange" to mod.prop("rs_version_range"),
        // e.g. 21.1.264 -> [21.1,) so players aren't forced onto the exact NeoForge build we compiled against
        "neoforgeVersionRange" to "[${mod.prop("neoforge_version", "0.0").substringBeforeLast('.')},)",
        "forgeLoaderVersion" to mod.prop("forge_loader_version", ""),
    )
}

publishMods {
    // Forge only started shipping Mixin in 1.16
    val needsMixinBootstrap = stonecutter.eval(minecraft, "<1.16")
    modrinth {
        requires("refined-storage")
        if (needsMixinBootstrap) requires("mixinbootstrap")
        if (mod.isFabric) requires("fabric-api")
    }
    curseforge {
        client = true
        server = true
        requires("refined-storage")
        if (needsMixinBootstrap) requires("mixinbootstrap")
        if (mod.isFabric) requires("fabric-api")
    }
}